ArduinoとGPSモジュールを使ったLCD時計の製作(２)：GPSモジュール変更

#include <Arduino.h>
#include <Wire.h>            // Arduino IDE のI2Cライブラリ
#include <TinyGPS++.h>       // https://github.com/mikalhart/TinyGPSPlus
#include <SoftwareSerial.h>
#include <TimeLib.h>
#include <LcdCore.h>         // LCDコアライブラリ
#include <LCD_ACM1602NI.h>   // 秋月I2C液晶用のI/Oライブラリ

#define time_offset 32400    // UTC+9時間(3600 * 9 秒）
static const int RXPin = 10, TXPin = 11;
static const uint32_t GPSBaud = 9600;
TinyGPSPlus gps;             // The TinyGPS++ object
SoftwareSerial ss(RXPin, TXPin); // The serial connection to the GPS device
LCD_ACM1602NI lcd(0xa0);         // 0xa0は液晶モジュールのI2Cアドレス
int o_sec;     // 古い秒の格納
int day_week;  // 曜日
char DayWeekData[7][4] = {"Sun","Mon","Tue","Wed","Thu","Fri","Sat"} ;


void setup(void)
{
Serial.begin(9600);
ss.begin(GPSBaud);
Wire.begin();       // I2C初期化
lcd.begin(16, 2);   // ディスプレイの行数(16)と桁数(2)
}


void loop()
{
  while (ss.available() > 0)
  {
    if (gps.encode(ss.read()))
    {
      if(o_sec != gps.time.second())  //GPSから取得した秒が変わったら時刻を更新
      {
        o_sec = gps.time.second();
        setTime(gps.time.hour(), gps.time.minute(), gps.time.second(), gps.date.day(), gps.date.month(), gps.date.year());
        adjustTime(time_offset);   //JST変換
// JSTの日付、曜日、時刻の表示
day_week = getDayWeek(year(), month(), day());
lcd.setCursor(0, 0);
lcd.print(year());
lcd.setCursor(4, 0);
lcd.print("/");
lcd.setCursor(5, 0);
lcdzeroSup(month());
lcd.setCursor(7, 0);
lcd.print("/");
lcd.setCursor(8, 0);
lcdzeroSup(day());
lcd.setCursor(11, 0);
lcd.print("(");
lcd.print(DayWeekData[day_week]) ;
lcd.print(")");
lcd.setCursor(0, 1);
lcdzeroSup(hour());
lcd.setCursor(2, 1);
lcd.print(":");
lcd.setCursor(3, 1);
lcdzeroSup(minute());
lcd.setCursor(5, 1);
lcd.print(":");
lcd.setCursor(6, 1);
lcdzeroSup(second());
      }
    }
  }
}
 
// 曜日の計算（ツェラー(Zeller)の公式)
int getDayWeek(int year,int month,int day)
{
int w ;
if(month < 3) 
{
year = year - 1;
month = month + 12 ;
}
w = (year + (year/4) - (year/100) + (year/400) + (13*month+8)/5 + day ) % 7;
return w;
}

// 月、日、時、分、秒が0～9の場合、1桁目を 空白 もしくは 0 に置換
void lcdzeroSup(int digit)
{
if(digit < 10)
lcd.print(' ');   // 現在「空白」
lcd.print(digit);
}