ESP32-DevKitCと DS3231を使ったRTC時計＆ BME280を使った温湿度・気圧計を20文字x4行LCDに表示：環境モニタ(2)

#include <Wire.h>
#include <Adafruit_Sensor.h>  // https://github.com/adafruit/Adafruit_Sensor
#include <Adafruit_BME280.h>  // https://github.com/adafruit/Adafruit_BME280_Library

Adafruit_BME280 bme;
float temp;
float pressure;
float humid;

void setup() {
Serial.begin(115200);
bool status;
status = bme.begin(0x76);
while (!status) {
Serial.println("BME280 sensorが使えません");
delay(1000);
}
}

void loop() {
temp=bme.readTemperature();
pressure=bme.readPressure() / 100.0F;
humid=bme.readHumidity();
Serial.print(temp);
Serial.print(" *C  ");
Serial.print(pressure);
Serial.print(" hPa  ");
Serial.print(humid);
Serial.println(" %");
delay(1000);
}

#include <Wire.h>
#include <WiFi.h>
#include <time.h>
#include <LiquidCrystal_I2C.h> // https://github.com/johnrickman/LiquidCrystal_I2C
#include <DS3232RTC.h>         // https://github.com/JChristensen/DS3232RTC
#include <esp_sntp.h>
#include <Adafruit_Sensor.h>   // https://github.com/adafruit/Adafruit_Sensor
#include <Adafruit_BME280.h>   // https://github.com/adafruit/Adafruit_BME280_Library

DS3232RTC myRTC(false);
LiquidCrystal_I2C lcd(0x27, 20, 4);    // DS3231時計、屋内BME280表示
Adafruit_BME280 bme;   // 屋内センサ
float temp;
float pressure;
float humid;
// 2022/03/27：曜日の文字数を9文字固定に変更
const char* weekStr[7] = {"Sunday   ","Monday   ","Tuesday  ","Wednesday","Thursday ","Friday   ","Saturday "};
const char* ssid      = "your ssid";
const char* password  = "your password";
const char* ntpServer = "ntp.nict.jp";
const long  gmtOffset_sec = 32400;
const int   daylightOffset_sec = 0;

void setup() {
  struct tm timeInfo;
  Serial.begin(115200);
  myRTC.begin();
  lcd.init();
  lcd.backlight();
// ----- DS3231時計 -----
//WiFi接続
  WiFi.begin(ssid, password);
  while(WiFi.status() != WL_CONNECTED) {
  lcd.print("."); // 進捗表示
  delay(500);
  }
// WiFi接続の表示
  lcd.clear();
  lcd.print("WiFi connected");
  delay(2000);
  lcd.clear();
// NTPサーバからJST取得
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);
  lcd.clear();
  lcd.print("JST synchro.");
  delay(2000);
  lcd.clear();
// 内蔵RTCの時刻がNTP時刻に合うまで待機
  while (sntp_get_sync_status() == SNTP_SYNC_STATUS_RESET) {
    lcd.print(">"); // 進捗表示
    delay(1000);
  }
//内蔵RTC時刻 = NTP時刻の表示
  lcd.clear();
  lcd.print("Time matched");
  delay(2000);
  lcd.clear();
// 内蔵RTCの時刻の取得
  getLocalTime(&timeInfo);
// 内蔵RTCの時刻をDS3231に時刻設定
  setTime(timeInfo.tm_hour, timeInfo.tm_min, timeInfo.tm_sec, timeInfo.tm_mday, timeInfo.tm_mon + 1, timeInfo.tm_year + 1900);
  myRTC.set(now());
//WiFi切断
  WiFi.disconnect(true);
  WiFi.mode(WIFI_OFF);
// ----- BME280温湿度・圧力計 -----
  bool status;
  status = bme.begin(0x76);  
  while (!status) {
    Serial.println("屋内BME280 sensorが使えません");
    delay(1000);
  }
}

void loop(void) {
dispLCD();
delay(1000);
}

void dispLCD(void) {
// ----- DS3231時計 -----
// RTCから時刻取得
  tmElements_t tm;
  myRTC.read(tm);
// 時計LCD表示
    lcd.setCursor(0,0);
      lcd.print(tm.Year + 1970);
      lcd.print("/");
      lcdzeroSup(tm.Month);
      lcd.print("/");
      lcdzeroSup(tm.Day);
      lcd.print(" ");
      lcd.setCursor(11,0);
      lcd.print(weekStr[tm.Wday - 1]);
      lcd.setCursor(0,1);
      lcdzeroSup(tm.Hour);
      lcd.print(":");
      lcdzeroSup(tm.Minute);
      lcd.print(":");
      lcdzeroSup(tm.Second);
// ----- BME280温湿度・圧力計 -----
// 屋内センサ
  temp=bme.readTemperature();
  pressure=bme.readPressure() / 100.0F;
  humid=bme.readHumidity();
    lcd.setCursor(0,2);
      lcd.print("PRESS1:");
      lcd.print(pressure,1);
      lcd.print("hPa");
    lcd.setCursor(0,3);
      lcd.print("T:");
      lcd.print(temp,1);
      lcd.print("'C / H:");
      lcd.print(humid,1);
      lcd.print("%");  
}

// ----- DS3231時計 -----
// 先頭のゼロ（0）を空白に置換
void lcdzeroSup(int digit) {
if(digit < 10)
lcd.print(' '); // 空白
lcd.print(digit);
}