ArduinoとGPSモジュールを使ったLCD時計の製作(３)：利用中の衛星数の表示

#include <Arduino.h>
#include <Wire.h>            // Arduino IDE のI2Cライブラリ
#include <TinyGPSPlus.h>     // https://github.com/mikalhart/TinyGPSPlus
#include <SoftwareSerial.h>
#include <TimeLib.h>
#include <LcdCore.h>         // LCDコアライブラリ
#include <LCD_ACM1602NI.h>   // 秋月I2C液晶用のI/Oライブラリ

#define time_offset 32400    // UTC+9時間(60*60*9 秒）
TinyGPSPlus gps;
SoftwareSerial ss(10, 11);   // RXPin = 10, TXPin = 11
LCD_ACM1602NI lcd(0xa0);     // 0xa0は液晶モジュールのI2Cアドレス

int jst_year;
int jst_month;
int jst_day;
int jst_hour;
int jst_minute;
int jst_second;
int day_week;
char DayWeekData[7][4] = {"Sun","Mon","Tue","Wed","Thu","Fri","Sat"} ;

void setup()
{
Serial.begin(9600);
ss.begin(9600);
Wire.begin();       // I2C初期化
lcd.begin(16, 2);   // ディスプレイの行数(16)と桁数(2)
}

void loop()
{
// GPSデータ取得
while (ss.available())
  gps.encode(ss.read());

// 利用中の衛星数の取得、表示
lcd.setCursor(10, 1);
lcd.print("s=");
if (gps.satellites.isValid())
{
lcd.setCursor(12, 1);
lcdzeroSup(gps.satellites.value());  // Number of satellites in use (u32)
} else {
lcd.setCursor(12, 1);
lcd.print("--");
}
// 分、時、日、月、年が変わったらGPS取得データで更新
if(jst_minute != gps.time.minute() || 
   jst_hour   != gps.time.hour()   || 
   jst_day    != gps.date.day()    || 
   jst_month  != gps.date.month()  || 
   jst_year   != gps.date.year() )
{
jst_day    =gps.date.day();
jst_month  =gps.date.month();
jst_year   =gps.date.year();
jst_hour   =gps.time.hour();
jst_minute =gps.time.minute();
jst_second =gps.time.second();
setTime(jst_hour, jst_minute, jst_second, jst_day, jst_month, jst_year);
// JST変換
adjustTime(time_offset);
}
// JSTの日付、曜日、時刻の表示
lcd.setCursor(0, 0);
lcd.print(year());
lcd.setCursor(4, 0);
lcd.print("/");
lcd.setCursor(5, 0);
lcdzeroSup(month());
lcd.setCursor(7, 0);
lcd.print("/");
lcd.setCursor(8, 0);
lcdzeroSup(day());
lcd.setCursor(11, 0);
lcd.print("(");
day_week = getDayWeek(year(), month(), day()); // 曜日の計算
lcd.print(DayWeekData[day_week]) ;
lcd.print(")");
lcd.setCursor(0, 1);
lcdzeroSup(hour());
lcd.setCursor(2, 1);
lcd.print(":");
lcd.setCursor(3, 1);
lcdzeroSup(minute());
lcd.setCursor(5, 1);
lcd.print(":");
lcd.setCursor(6, 1);
lcdzeroSup(second());
}

// 曜日の計算（ツェラー(Zeller)の公式)
int getDayWeek(int year,int month,int day)
{
int w ;
if(month < 3) 
{
year = year - 1;
month = month + 12 ;
}
w = (year + (year/4) - (year/100) + (year/400) + (13*month+8)/5 + day ) % 7;
return w;
}

// 値が0～9の場合、1桁目を 空白 もしくは 0 に置換
void lcdzeroSup(int digit)
{
if(digit < 10)
lcd.print(' ');   // 現在「空白」
lcd.print(digit);
}