Arduino MEGA 2560 Rev3と3.5インチ480×320液晶シールドにBME280をI2C接続して気圧・温湿度を表示、microSDカード記録

//3.5 INCH TFT Display Shield with Arduino MEGA 2560 Rev3
#include <Adafruit_GFX.h>    // Core graphics library
#include <MCUFRIEND_kbv.h>   // Hardware-specific library
MCUFRIEND_kbv tft;
#include <Fonts/FreeMonoBold24pt7b.h>
#include <Fonts/FreeMonoBold12pt7b.h>
#define BLACK   0x0000
#define RED     0xF800
#define GREEN   0x07E0
#define WHITE   0xFFFF
#define GREY    0x8410
#define YELLOW  0xFFE0

#include <SPI.h>
#include <SD.h>
File dataFile;

#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>  // BME280_Library

Adafruit_BME280 bme;   // 気圧・温湿度センサ
float pres;
float temp;
float humi;
String op; 
String ot; 
String oh; 
String np; 
String nt; 
String nh; 


void setup(void){
 Serial.begin(9600);
// TFTライブラリ初期化
 tft.reset();
 uint16_t ID = tft.readID();
 if (ID == 0xD3D3) ID = 0x9486; //force ID if write-only display
 tft.begin(ID);
 tft.setRotation(1);
 tft.fillScreen(BLACK);
    tft.setFont(&FreeMonoBold12pt7b);
    tft.setTextSize(1);
    tft.setCursor(0, 40);
    tft.setTextColor(WHITE,BLACK);
      tft.print("TFT ID...");
    tft.setTextColor(GREEN,BLACK);
      tft.print(ID,HEX);   
delay(1000);
// SDカードマウント確認
    tft.setCursor(0, 80);
    tft.setTextColor(WHITE,BLACK);
      tft.print("Initializing SD card...");
  if (!SD.begin(53)) {          // CS - pin 53
    tft.setTextColor(RED,BLACK);
      tft.print("failed!");
    while (1);
  }
    tft.setTextColor(GREEN,BLACK);
      tft.print("done.");
delay(1000);
// SDカードファイル書き込み
    tft.setCursor(0, 120);
    tft.setTextColor(WHITE,BLACK);
      tft.print("File written...");
dataFile = SD.open("/datalog.txt", FILE_WRITE);
dataFile.println("datalog.txt");
dataFile.close();
    tft.setTextColor(GREEN,BLACK);
      tft.print("datalog.txt");
delay(1000);
// Wireライブラリ初期化
Wire.begin();
// BME280初期化
    tft.setCursor(0, 160);
    tft.setTextColor(WHITE,BLACK);
       tft.print("BME280...");
 if (!bme.begin(0x76)) {
    tft.setTextColor(RED,BLACK);
       tft.print("connection failed");
    while (1);
  }
    tft.setTextColor(GREEN,BLACK);
       tft.print("connected");
delay(1000);
// 項目名の表示
    tft.fillScreen(BLACK);
    tft.setFont(&FreeMonoBold24pt7b);
    tft.setTextSize(1);
    tft.setTextColor(WHITE,BLACK);
    tft.setCursor(0, 40);
       tft.print("Pres:");
    tft.setTextColor(GREY,BLACK);
    tft.setCursor(0, 85);
       tft.print("(hPa)");
    tft.setTextColor(WHITE,BLACK);
    tft.setCursor(0, 150);
       tft.print("Temp:");
    tft.setTextColor(GREY,BLACK);
    tft.setCursor(20, 195);
       tft.print("( ");
    tft.setCursor(65, 195);
       tft.print("C)");
    tft.setTextSize(2);
    tft.setCursor(29, 175);
       tft.print(".");
    tft.setTextColor(BLACK,BLACK);
    tft.setTextSize(1);
    tft.setCursor(44, 174);
       tft.print(".");
    tft.setTextColor(WHITE,BLACK);
    tft.setCursor(0, 260);
       tft.print("Humi:");
    tft.setTextColor(GREY,BLACK);
    tft.setCursor(20, 305);
       tft.print("(%)");
}


void loop(void){
// ----- BME280センサからデータ取得 ----- 
pres=bme.readPressure() / 100.0F;
temp=bme.readTemperature();
humi=bme.readHumidity();
    tft.setFont(&FreeMonoBold24pt7b);
    tft.setTextSize(3);
    tft.setTextColor(GREEN,BLACK);  // FreeFONTでは背景色指定は無効
// ----- 液晶画面に気圧、温度、湿度の測定値を表示 ----- 
// 気圧表示（前後で測定値が変わったら黒背景で前の文字消去）
np = String(pres, 0);
 if( np != op ) {
    tft.fillRect(150,0,329,105,BLACK);
  }
    tft.setCursor(150, 95);
    tft.print(np);  // 気圧
 op = np;
// 気温表示（前後で測定値が変わったら黒背景で前の文字消去）
nt = String(temp, 1);
 if( nt != ot ) {
        tft.fillRect(150,105,329,110,BLACK);
  }
    tft.setCursor(150, 205);
    tft.print(nt);  // 気温
 ot = nt;
// 湿度表示（前後で測定値が変わったら黒背景で前の文字消去）
nh = String(humi, 1);
 if( nh != oh ) {
       tft.fillRect(150,215,329,105,BLACK);
  }
    tft.setCursor(150, 315);
    tft.print(nh);  // 湿度
 oh = nh;
// ----- SDカードへの書き込み用データファイルの生成 ----- 
// 経過時間millis()を秒に変換
    String dataString = "";
    dataString += String(millis() / 1000); 
// 測定データ1：BME280の気圧
    dataString += ",";  // カンマセパレータ
    if(!isnan(pres)){
      dataString += String(pres);
    }else{
      dataString += " ";
    }
// 測定データ2：BME280の温度
    dataString += ",";  // カンマセパレータ
    if(!isnan(temp)){
      dataString += String(temp);
    }else{
      dataString += " ";
    }
// 測定データ3：BME280の湿度
    dataString += ",";  // カンマセパレータ
    if(!isnan(humi)){
      dataString += String(humi);
    }else{
      dataString += " ";
    }
// ----- SDカードのdatalog.txtにdataStringを追加 ----- 
dataFile = SD.open("/datalog.txt", FILE_WRITE);
dataFile.println(dataString);
dataFile.close();
// 測定間隔を調整
delay(2000);
}

//3.5 INCH TFT Display Shield with Arduino MEGA 2560 Rev3
#include <SPI.h>
#include <SD.h>
File dataFile;

void setup() {
Serial.begin(9600);
// SDカードマウント確認
  if (!SD.begin(53)) {   // CS - pin 53
Serial.println("card failed.");
  return;
  }
Serial.println("card connected.");

 //ファイルを読み込み
dataFile = SD.open("/datalog.txt");
  if (dataFile) {
    while (dataFile.available()) {
      Serial.write(dataFile.read());
    }
dataFile.close();
  } else {
  Serial.println("File not found.");
  }
}
  
void loop() {
}

//3.5 INCH TFT Display Shield with Arduino MEGA 2560 Rev3
#include <SPI.h>
#include <SD.h>
File dataFile;

void setup(){
Serial.begin(9600);
// SDカードマウント確認
  if (!SD.begin(53)) {   // CS - pin 53
Serial.println("Card failed.");
  return;}
Serial.println("card connected.");

 //ファイルを削除
if (SD.exists("datalog.txt")) {
    SD.remove("datalog.txt");
}
Serial.println("File removed.");

 //ファイルを読み込み確認
dataFile = SD.open("/datalog.txt");
  if (dataFile) {
    while (dataFile.available()) {
      Serial.write(dataFile.read());
    }
dataFile.close();
  } else {
  Serial.println("File not found.");
  }
}

void loop(){
  }